امائونٽ ان ورڊس MS Excel 2007

[JUSTIFY]سنڌ سلامت جا پيارا دوستو،
اميد آهي ته توهان سڀ خيريت سان خوش هوندا، اڄ جڏهن منهنجي نظر مائڪروسافٽ آفيس جي سيڪشن تي پئي، ته سيڪشن جا موضوع ڏٺم ته ڪابه اهڙي ٽپ نظر نه آئي جنهن حوالي سان دوستن کي سهڻي قسم جي ڄاڻ مهيا ٿي هجي، پوءِ ذهن ۾ خيال پيدا ٿيو ته ڇو نه مان اهڙي قسم جي ٽپ دوستن سان ونڊ ڪريان جيڪا دوستن لاءِ انتهائي ڪارائتي ثابت ٿئي، اميد ڪريان ٿو ته اڄ جيڪا مان توهان سان ٽپ ونڊ ڪري رهيو آهيان اها توهان کي ضرور پسند ايندي،

دوستو مائڪروسافٽ ايڪسل تمام هڪ وصيح پروگرام آهي، ايڪسل کي مان اڃان تائين ايترو نه سمجهي سگهيو آهيان، منهنجي ذهن ۾ جيڪو عِلم آهي اهو ته مان توهان سان ضرور ونڊ ڪري سگهان ٿو،
انسان سمجهندو آهي ته منهنجو ذهن ڪافي تيز آهي، مان ان ڳالهه کي مڃان ٿو، پر انسان جي سوچ ۽ سمجهه جو پنهنجو انداز هوندو آهي، هر هڪ انسان جي سوچ مختلف هوندي آهي، ته ايڪسل به هڪ اهڙو سافٽويئر آهي جنهن کي اسين پنهنجي سوچ مطافق استعمال ڪري سگهون ٿا،
ايڪسل کي مان اڪائونٽن ۽ رپورٽس انالائسس جي حوالي سان استعمال ڪندو آهيان،

ايڪسل ۾ اسين هڪ اهڙي پروگرامنگ جو ڪوڊ لڳائي سگهو ٿا جنهن سان ڪنهن به Cell جو امائونٽ اسان کي ورڊس ۾ظاهر ٿئي ته اهو ممڪن آهي، ان قسم جي پروگرامن کي VBA چيو ويندو آهي، اهو عمل ڪرڻ لاءِ VBA ڪوڊ توهان کي ان ايڪسل فائل جي Code ۾ Module ٺاهي رکڻو آهي۔

سڀ کان پهريان توهان ايڪسل فائل اوپن ڪريو جنهن فائل ۾ توهان اهڙي قسم جو عمل ڪرڻ چاهيو ٿا، ايڪسل فائل جون ڊفالٽ 3 شيٽس هونديون آهن، ڪنهن به هڪ شيٽ تي رائيٽ ڪلڪ ڪريو ۽ View Code تي ڪلڪ ڪري ڪريو، يا وري Alt + F11 بٽڻ پريس ڪريو، ان کان پوءِ‌ توهان جي اسڪرين تي هڪ ونڊوز اچي ويندي جيڪي هن ريت هوندي۔

5 اٽيچمينٽ ڏسو ​

پوءِ سائيڊ بار ۾ ڪنهن به شيٽ تي رائيٽ ڪلڪ ڪري Insert تي اچي Module تي ڪلڪ ڪرڻو آهي، پوءِ توهان جي اسڪرين تي هڪ ونڊو اچي ويندي جنهن ۾ هيٺ ڏنل ڪوڊ Paste ڪريو، پوءِ Ctrl + W بٽڻ پريس ڪري SAVE ڪريو ۽ Alt + F4 بٽڻ پريس ڪري ونڊو بند ڪريو۔

ڪوڊ:

Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
    Dim Rupees, Paisas, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert paisas and set MyNumber to rupees amount.
    If DecimalPlace > 0 Then
        Paisas = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Rupees
        Case ""
            Rupees = "No Rupees"
        Case "One"
            Rupees = "One Rupee"
         Case Else
            Rupees = Rupees & " Rupees"
    End Select
    Select Case Paisas
        Case ""
            Paisas = " Only"
        Case "One"
            Paisas = " Only"
              Case Else
            Paisas = " and " & Paisas & " Paisas Only"
    End Select
    SpellNumber = Rupees & Paisas
End Function
      
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function
      
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function
     
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

جي ها هاڻي توهان جي فائل ۾ اهو فنڪشن ايڊ ٿي ويو آهي، ان فنڪشن کي ڪال ڪرڻ لاءِ توهان ڪنهن به Cell ۾ ڪوبه امائونٽ لکو ۽ ان کي ڪال ڪرايو ڪنهن به Cell تي هي ڪوڊ لڳائي =SpellNumber(A1) جيئن هيٺ ڏنل تصوير ۾ آهي۔

6 اٽيچمينٽ ڏسو ​

دوست اميد ڪريان ٿو ته توهان کي منهنجو هي موضوع ضرورو پسند آيو هوندو،
دعائن ۾ ياد۔
[/JUSTIFY]

 

جواب: امائونٽ ان ورڊس MS Excel 2007

مهرباني سائين، پر شڪايت ڪهڙي آهي ؟ ؟ ؟

 

جواب: امائونٽ ان ورڊس MS Excel 2007

جي سائين توهان جو شڪايتون جلدي ختم ٿي وينديون۔

 

جواب: امائونٽ ان ورڊس MS Excel 2007

مهرباني ادا عامر

امائونٽ ان ورڊس لاء هڪ ٻيو ايڪسل ايڊز ان پڻ ايندو آهي۔ جيڪو هڪ دفعو انسٽال ڪرڻ کانپوء ايڪسل جو فارمولو ٿي ويندو آهي ۽ ٻيهر ڪٿي به ڪنهن به فائل ۾ ٻيهر ڪو اسڪرپٽ لڳائڻ جي ضرورت نا
هي هوندي۔

ان لاء AmountInWords نالي هڪ ايڊون هت ڪلڪ ڪري ڊائونلوڊ ڪريو۔ هاڻي ان کي ايڪسٽريٽ ڪري انسٽال ڪيو۔ هاڻ ايڪسل پاڻمرادو کلندي ۽ Enable Macros تي ڪلڪ ڪيو۔



ان کانپوء ايڪسل کوليو ۽ تصويرن ۾ سمجهايل طريقي کي عمل ۾ آڻيو۔

سڀ کان پهرين Excel Options تي ڪلڪ ڪيو۔



هاڻي هڪ نئين ونڊو کُلندي جتان Add-Ins تي ڪلڪ ڪيو



انکانپوء Excel Add-Ins ۽ پوء Go تي ڪلڪ ڪيو



انکانپوء ايڊز انز جي هڪ ننڍي پوپ اپ ونڊو کلندي جتي برائوز تي ڪلڪ ڪري امائونٽ ان ورڊز واري فائل تي ڪلڪ ڪيو۔ هاڻي اوڪي تي ڪلڪ ڪيو۔





اوهان ڏسندا ته Amountinwords جو ايڊ انز ايڊ ٿيو هوندو۔ هاڻي او ڪي تي ڪلڪ ڪيو ۽ ايڪسل کي بند ڪيو۔



هاڻي ايڪسل کوليو ۽ اوهان جتي چاهيو اتي اهو فارمولو لکو ۽ امائونٽ ان ورڊز جي فارمولي جو فائدو وٺو۔

سڀ کان پهريان رقم لکو

هاڻي مطلوبه سيل ۾ هي فارمولو لکو

ڪوڊ:

=amountinwords(B3)

ياد رکو ته مٿي بي 3 سيل نمبر آهي.